######################################################

##

## EXERCISE 8

##

######################################################

## Find the given name, last name and birthdate for all persons born between 1950 and 1970. Order by family name, then by first name.

#

SELECT DISTINCT ?givenName ?familyName ?birthdate

WHERE {

 ?person schema:givenName ?givenName .

 ?person schema:familyName ?familyName .

 ?person schema:birthDate ?birthdate .

 FILTER ( ?birthdate > "1950-01-01"^^xsd:date && ?birthdate < "1970-01-01"^^xsd:date )

} ORDER BY ?familyName ?givenName

## Find the first and last name of all persons whose family name is not Kennedy

#

SELECT ?person ?givenName ?familyName

WHERE {

 ?person schema:givenName ?givenName .

 ?person schema:familyName ?familyName .

 FILTER ( ?familyName != "Kennedy")

}

## Find all persons that have at least two spouses listed for them. In the result table, show person, spouse 1 and spouse 2

#

SELECT ?person ?spouse1 ?spouse2

WHERE {

 ?person schema:spouse ?spouse1 .

 ?person schema:spouse ?spouse2 .

 FILTER ( ?spouse1 != ?spouse2 )

}

## Find for every person in the graph all aunts and their birthdate, and the parent that is the brother or sister of the aunt.

#

SELECT DISTINCT ?person ?parent ?aunt ?birthdate

WHERE {

 ?person schema:parent ?parent .

 ?parent schema:parent ?grandparent .

 ?aunt schema:parent ?grandparent .

 ?aunt schema:gender "female" .

 ?aunt schema:birthDate ?birthdate .

 FILTER ( ?aunt != ?parent )

} ORDER BY ?person